guild_vs4 mapflag nomemo
guild_vs4 mapflag pvp
guild_vs4 mapflag noreturn

guild_vs4,0,0,0 script ctf_sys -1,{
end;

OnBlueScore:
soundeffectall "DominationWin.wav", 0, "guild_vs4";
mapannounce "guild_vs4", "Раунд выигран Синей Командой!",bc_map,0x0000FF;
if(.team[2] == .team[1])
soundeffectall "BlTakesTheLead.wav", 0, "guild_vs4";
else if(.team[2] > .team[1])
soundeffectall "BlueTeamIncreases.wav", 0, "guild_vs4";
else
soundeffectall "BlueTeamScores.wav", 0, "guild_vs4";
set .team[2], .team[2] + 1;
goto OnStart;

OnRedScore:
soundeffectall "DominationWin.wav", 0, "guild_vs4";
mapannounce "guild_vs4", "Раунд выигран Красной Командой!",bc_map,0xFF0000;
if(.team[1] == .team[2])
soundeffectall "RedTeamTakesTheLead.wav", 0, "guild_vs4";
else if(.team[1] > .team[2])
soundeffectall "RedTeamIncreases.wav", 0, "guild_vs4";
else
soundeffectall "RedTeamScores.wav", 0, "guild_vs4";
set .team[1], .team[1] + 1;

OnStart:
if($@ctfevent_start >= $@ctf_rnd && .team[2] != .team[1]) goto L_Stop;
set $@ctfevent_start, $@ctfevent_start + 1;
set $@ctf_fb, 0;
set .@total, getarraysize($@ctf_db_1);
enablenpc "ctf_rflag";
enablenpc "ctf_bflag";
movenpc "ctf_bflag", 91, 49;
movenpc "ctf_rflag", 7, 49;
set $@ctf_rtaken, 0;
set $@ctf_btaken, 0;
for(set .@i, 0; .@i < .@total; set .@i, .@i + 1){
attachrid getelementofarray($@ctf_db_1, .@i);
pcblockmove 0,1;
dispbottom "Сейчас начнется поединок! Вы принадлежите к Красной Команде.";
dispbottom "Старайтесь захватить Синий Флаг и отнести его на свою базу!";
warp "guild_vs4",49,91;
savepoint "guild_vs4",49,91;
detachrid;
}
set .@total, getarraysize($@ctf_db_2);
for(set .@i, 0; .@i < .@total; set .@i, .@i + 1){
attachrid getelementofarray($@ctf_db_2, .@i);
pcblockmove 0,1;
dispbottom "Сейчас начнется поединок! Вы принадлежите к Синей Команде.";
dispbottom "Старайтесь захватить Красный Флаг и отнести его на свою базу!";
warp "guild_vs4",50,7;
savepoint "guild_vs4",50,7;
detachrid;
}
sleep 5000;
soundeffectall "NewRound.wav", 0, "guild_vs4";
mapannounce "guild_vs4", "[Раунд " + $@ctfevent_start + "] Начнется через ...", 16;
initnpctimer;
end;

L_Stop:
if(.team[1] > .team[2]){
mapannounce "guild_vs4", "Поединок закончен! Победила Красная Команда!", bc_map,0xFF0000;
set .@total, getarraysize($@ctf_db_1);
for(set .@i, 0; .@i < .@total; set .@i, .@i + 1){
attachrid getelementofarray($@ctf_db_1, .@i);
soundeffect "YouHaveWonTheMatch.wav", 0;
set Zeny, Zeny + $@ctf_rew;
set @ctf, 0;
set @ctf_com, 0;
set @ctf_kill, 0;
set @ctf_time, 0;
set @ctf_taker, 0;
savepoint "prontera",185,205;
detachrid;
}
set .@total, getarraysize($@ctf_db_2);
for(set .@i, 0; .@i < .@total; set .@i, .@i + 1){
attachrid getelementofarray($@ctf_db_2, .@i);
soundeffect "YouHaveLostTheMatch.wav", 0;
set @ctf, 0;
set @ctf_com, 0;
set @ctf_kill, 0;
set @ctf_time, 0;
set @ctf_taker, 0;
savepoint "prontera",185,205;
detachrid;
}
}else{
mapannounce "guild_vs4", "Поединок закончен! Победила Синяя Команда!",bc_map,0x0000FF;
set .@total, getarraysize($@ctf_db_1);
for(set .@i, 0; .@i < .@total; set .@i, .@i + 1){
attachrid getelementofarray($@ctf_db_1, .@i);
set @ctf, 0;
set @ctf_com, 0;
set @ctf_kill, 0;
soundeffect "YouHaveLostTheMatch.wav", 0;
set @ctf_time, 0;
set @ctf_taker, 0;
savepoint "prontera",185,205;
detachrid;
}
set .@total, getarraysize($@ctf_db_2);
for(set .@i, 0; .@i < .@total; set .@i, .@i + 1){
attachrid getelementofarray($@ctf_db_2, .@i);
set @ctf, 0;
set @ctf_com, 0;
set @ctf_kill, 0;
soundeffect "YouHaveWonTheMatch.wav", 0;
set Zeny, Zeny + $@ctf_rew;
set @ctf_time, 0;
savepoint "prontera",185,205;
set @ctf_taker, 0;
detachrid;
}
}
L_Clean:
set $@ctfevent_start, 0;
deletearray $@ctf_db_1, getarraysize($@ctf_db_1);
deletearray $@ctf_db_2, getarraysize($@ctf_db_2);
deletearray .team, getarraysize(.team);
set $@ctf_fb, 0;
sleep 5000;
mapwarp "guild_vs4", "prontera", 185, 205;
end;

OnTimer4000:
mapannounce "guild_vs4", "5!",16;
soundeffectall "ctf5.wav", 0, "guild_vs4";
end;
OnTimer5000:
mapannounce "guild_vs4", "4!",16;
soundeffectall "ctf4.wav", 0, "guild_vs4";
end;
OnTimer6000:
mapannounce "guild_vs4", "3!",16;
soundeffectall "ctf3.wav", 0, "guild_vs4";
end;
OnTimer7000:
mapannounce "guild_vs4", "2!",16;
soundeffectall "ctf2.wav", 0, "guild_vs4";
end;
OnTimer8000:
mapannounce "guild_vs4", "1!",16;
soundeffectall "ctf1.wav", 0, "guild_vs4";
end;
OnTimer9000:
set .@total, getarraysize($@ctf_db_1);
for(set .@i, 0; .@i < .@total; set .@i, .@i + 1){
pcblockmove getelementofarray($@ctf_db_1, .@i),0;
}
set .@total, getarraysize($@ctf_db_2);
for(set .@i, 0; .@i < .@total; set .@i, .@i + 1){
pcblockmove getelementofarray($@ctf_db_2, .@i),0;
}
soundeffectall "ctfPlay.wav", 0, "guild_vs4";
end;

OnInit:
set $@ctf_max, 6;
set $@ctf_rnd, 5;
set $@ctf_rew, 10000;
end;

OnPCKillEvent:
if(@ctf && $@ctfevent_start){
if($@ctf_fb == 0){
set $@ctf_fb, 1;
mapannounce "guild_vs4", strcharinfo(0) + " drew the FIRST BLOOD!", 16;
soundeffectall "FirstBlood.wav", 0, "guild_vs4";
}
set @ctf_kill, @ctf_kill + 1;
if(gettimetick(2) - @ctf_time < 10){
set @ctf_time, gettimetick(2);
set @ctf_com, @ctf_com + 1;
switch(@ctf_com){
case 1: // 2 kills
announce strcharinfo(0) + " got a Double Kill!", bc_self;
soundeffectall "DoubleKill.wav", 0, "guild_vs4";
break;
case 2:
announce strcharinfo(0) + " got a Triple Kill!", bc_self;
soundeffectall "TripleKill.wav", 0, "guild_vs4";
break;
case 3:
announce strcharinfo(0) + " got a Multi Kill!", bc_self;
soundeffectall "MultiKill.wav", 0, "guild_vs4";
break;
case 4:
announce strcharinfo(0) + " got a Ultra Kill!", bc_self;
soundeffectall "UltraKill.wav", 0, "guild_vs4";
break;
case 5:
announce strcharinfo(0) + " got a Mega Kill!", bc_self;
soundeffectall "MegaKill.wav", 0, "guild_vs4";
break;
case 6:
announce strcharinfo(0) + " got a MOOOOOOOONSTER Kill!", bc_self;
soundeffectall "MonsterKill.wav", 0, "guild_vs4";
break;
case 7:
announce strcharinfo(0) + " got a LLLLLLLLUUUUDDDRRICCOOOOUSS Kill!", bc_self;
soundeffectall "LudricousKill.wav", 0, "guild_vs4";
break;
default: // Holy shit!
announce strcharinfo(0) + " got a HOLY SHIT!", bc_self;
soundeffectall "HolyShit.wav", 0, "guild_vs4";
break;
}
sleep2 3000;
} else {
set @ctf_time, gettimetick(2);
set @ctf_com, 0;
}
if(@ctf_kill > 30){
announce strcharinfo(0) + " is a WICKED SICK!", bc_self;
soundeffectall "WickedSick.wav", 0, "guild_vs4";
} else if(@ctf_kill > 25){
announce strcharinfo(0) + " is a GODLIKE!", bc_self;
soundeffectall "Godlike.wav", 0, "guild_vs4";
} else if(@ctf_kill > 20){
announce strcharinfo(0) + " is a DOMINATING!", bc_self;
soundeffectall "Dominating.wav", 0, "guild_vs4";
} else if(@ctf_kill > 15){
announce strcharinfo(0) + " is a UNSTOPPABLE!", bc_self;
soundeffectall "Unstoppable.wav", 0, "guild_vs4";
} else if(@ctf_kill > 10){
announce strcharinfo(0) + " is a RAMPAGE!", bc_self;
soundeffectall "Rampage.wav", 0, "guild_vs4";
} else if(@ctf_kill > 5){
mapannounce "guild_vs4", strcharinfo(0) + " has pwned " + rid2name(killerrid) + " is now on a Killing Spree!",16;
soundeffectall "KillingSpree.wav", 0, "guild_vs4";
}
}
end;

OnPCDieEvent:
if(@ctf && $@ctfevent_start){
set @ctf_com, 0;
set @ctf_time, 0;
if(@ctf_kill> 5){
mapannounce "guild_vs4", rid2name(killerrid) + " has ended " + strcharinfo(0) + "'s Killing Spree!",16;
}
set @ctf_kill,0;
if(@ctf_taker){
if(getmapxy(.@m$,.@x,.@y,0) != 0)
end;
if(@ctf == 1){
enablenpc "ctf_bflag";
movenpc "ctf_bflag", .@x, .@y;
mapannounce "guild_vs4", "Синий Флаг утерян!",bc_map,0x0000FF;
soundeffectall "BlueFlagDropped.wav", 0, "guild_vs4";
}else{
enablenpc "ctf_rflag";
movenpc "ctf_rflag", .@x, .@y;
mapannounce "guild_vs4", "Красный Флаг утерян!",bc_map,0xFF0000;
soundeffectall "RedFlagDropped.wav", 0, "guild_vs4";
}
set @ctf_taker, 0;
}
}
end;

OnPCLogoutEvent:
if(@ctf){
set ctf_li, 1;
savepoint "prontera",185,205;
callfunc "ctf_rem", getd("$@ctf_db_" + @ctf), playerattached();
if(@ctf_taker){
if(getmapxy(.@m$,.@x,.@y,0) != 0)
end;
if(@ctf == 1){
enablenpc "ctf_bflag";
movenpc "ctf_bflag", .@x, .@y;
mapannounce "guild_vs4", "Синий Флаг утерян!",bc_map,0x0000FF;
soundeffectall "BlueFlagDropped.wav", 0, "guild_vs4";
}else{
enablenpc "ctf_rflag";
movenpc "ctf_rflag", .@x, .@y;
mapannounce "guild_vs4", "Красный Флаг утерян!",bc_map,0xFF0000;
soundeffectall "RedFlagDropped.wav", 0, "guild_vs4";
}
}
if(getarraysize($@ctf_db_1) == 0 && getarraysize($@ctf_db_2) == 0) goto L_Clean;
}
end;

OnPCLoadMapEvent:
if(ctf_li){
set ctf_li, 0;
warp "prontera",185,205;
}
end;
}

function script ctf_rem {
set .@total, getarraysize(getarg(0));
for(set .@i, 0; .@i < .@total; set .@i, .@i + 1){
if(getelementofarray(getarg(0), .@i) == getarg(1))
break;
}
if(.@i < .@total)
deletearray getelementofarray(getarg(0), .@i), 1;
return;
}

guild_vs4,7,49,4 script Красный Флаг::ctf_rflag 722,2,2,{
end;
OnTouch:
if(@ctf && $@ctfevent_start){
if(@ctf == 1){
if($@ctf_rtaken != 0){
movenpc "ctf_rflag", 7, 49;
mapannounce "guild_vs4", "Красный Флаг возвращен на исходную позицию!",bc_map,0xFF0000;
soundeffectall "RedFlagReturned.wav", 0, "guild_vs4";
set $@ctf_rtaken, 0;
}
end;
}
set $@ctf_rtaken, 1;
set @ctf_taker, 1;
mapannounce "guild_vs4", "Красный Флаг захвачен!",bc_map,0xFF0000;
soundeffectall "RedFlagTaken.wav", 0, "guild_vs4";
disablenpc "ctf_rflag";
}
end;
}

guild_vs4,91,49,4 script Синий Флаг::ctf_bflag 722,2,2,{
end;
OnTouch:
if(@ctf && $@ctfevent_start){
if(@ctf == 2){
if($@ctf_btaken != 0){
movenpc "ctf_bflag", 91, 49;
mapannounce "guild_vs4", "Синий Флаг возвращен на исходную позицию!",bc_map,0x0000FF;
soundeffectall "BlueFlagReturned.wav", 0, "guild_vs4";
set $@ctf_btaken, 0;
}
end;
}
set $@ctf_btaken, 1;
set @ctf_taker, 1;
mapannounce "guild_vs4", "Синий Флаг захвачен!",bc_map,0x0000FF;
soundeffectall "BlueFlagTaken.wav", 0, "guild_vs4";
disablenpc "ctf_bflag";
}
end;
}

guild_vs4,50,91,4, script База Красных::ctf_rbase 858,2,2,{
end;
OnTouch:
if(@ctf == 2) end;
if(@ctf && $@ctfevent_start){
percentheal 100,100;
if(@ctf_taker && $@ctf_rtaken == 0){
set @ctf_taker, 0;
donpcevent "ctf_sys::OnRedScore";
}
}
end;
}

guild_vs4,49,8,4, script База Синих::ctf_bbase 858,2,2,{
end;
OnTouch:
if(@ctf == 1) end;
if(@ctf && $@ctfevent_start){
percentheal 100,100;
if(@ctf_taker && $@ctf_btaken == 0){
set @ctf_taker, 0;
donpcevent "ctf_sys::OnBlueScore";
}
}
end;
}

function script ctf_reg {
if(getgmlevel() == 99){
switch(select("Продолжить","Конфигурация")){
case 2:
mes "Человек в комманде:";
input $@ctf_max;
mes $@ctf_max;
mes "Количество раундов:";
input $@ctf_rnd;
mes $@ctf_rnd;
mes "Денежный приз каждому из победителей:";
input $@ctf_rew;
mes $@ctf_rew;
next;
default:
break;
}
}
L_menu:
mes "[Организатор]";
mes "^FF0000Красная команда^000000 - " + getarraysize($@ctf_db_1) + " / " + $@ctf_max;
mes "^0000FFСиняя команда^000000 - " + getarraysize($@ctf_db_2) + " / " + $@ctf_max;
next;
switch(select("Регистрация","Состав команд","Информация")){
case 1:
if(Zeny < ($@ctf_rew/2)){
mes "[Организатор]";
mes "Извините, у вас недостаточно средств для взноса в призовой фонд поединка (" + $@ctf_rew/2 + ").";
close;
}
if(@ctf || @ddomination){
mes "[Организатор]";
mes "Извините, вы не можете зарегистрироваться дважды.";
close;
}
mes "[Организатор]";
mes "За какую комманду желаете сражаться?";
next;
set .@size1, getarraysize($@ctf_db_1);
set .@size2, getarraysize($@ctf_db_2);
switch(select("^FF0000Красная команда^000000","^0000FFСиняя команда^000000")){
case 1:
if($@ctf_max > .@size1)
callfunc "ctf_sign", 1, playerattached();
else
set .@reg_f,1;
break;
case 2:
if($@ctf_max > .@size2)
callfunc "ctf_sign", 2, playerattached();
else
set .@reg_f,1;
break;
}
if(.@reg_f) {
mes "[Организатор]";
mes "Извините, на данный момент регистрация закончена.";
close;
}
break;
case 2:
select "^FF0000Красная команда^000000","^0000FFСиняя команда^000000";
//next;
set .@total, getarraysize(getd("$@ctf_db_" + @menu));
if (.@total)
for(set .@i, 0; .@i < .@total; set .@i, .@i + 1)
mes rid2name(getelementofarray(getd("$@ctf_db_" + @menu), .@i));
else{
mes "[Организатор]";
mes "Команда не набрана.";
}
next;
goto L_menu;
case 3:
//next;
mes "[Организатор]";
mes "В поединке `Захват Флага`";
mes "необходимо захватить флаг";
mes "противника и отнести его на";
mes "свою базу, попутно охраняя";
mes "свой флаг.";
next;
mes "[Организатор]";
mes "Стоимость участия - " + $@ctf_rew/2 + " зеней.";
mes "В случае выигрыша вы получите - " + $@ctf_rew + " зеней.";
next;
goto L_menu;
}
close;
}

function script ctf_sign {
set Zeny, Zeny - ($@ctf_rew/2);
set getd("$@ctf_db_" + getarg(0) + "[" + getarraysize(getd("$@ctf_db_" + getarg(0))) + "]"), getarg(1);
set @ctf, getarg(0);
mes "[Организатор]";
if(@ctf == 1)
mes "Вы присоединились к ^FF0000Красной Команде^000000.";
else
mes "Вы присоединились к ^0000FFСиней Команде^000000.";
close2;
set .@size, getarraysize($@ctf_db_1);
if(.@size == getarraysize($@ctf_db_2) && .@size == $@ctf_max && $@ctfevent_start == 0)
donpcevent "ctf_sys::OnStart";
end;
}

prontera,187,210,4 script Организатор ПЗФ 952,{
callfunc "ctf_reg";
end;
}